tripz-llc/apps/driver/android/app/build.gradle

plugins {
    id "com.android.application"
    // START: FlutterFire Configuration
    id 'com.google.gms.google-services'
    // END: FlutterFire Configuration
    id "kotlin-android"
    // The Flutter Gradle Plugin must be applied after the Android and Kotlin Gradle plugins.
    id "dev.flutter.flutter-gradle-plugin"
}

def keystoreProperties = new Properties()
def keystorePropertiesFile = rootProject.file('key.properties')
// Load keystore properties if the file exists
if (keystorePropertiesFile.exists()) {
    keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
}

def localProperties = new Properties()
def localPropertiesFile = rootProject.file('local.properties')
if (localPropertiesFile.exists()) {
    localPropertiesFile.withReader('UTF-8') { reader ->
        localProperties.load(reader)
    }
}

def flutterVersionCode = localProperties.getProperty('flutter.versionCode')
if (flutterVersionCode == null) {
    flutterVersionCode = '1'
}

def flutterVersionName = localProperties.getProperty('flutter.versionName')
if (flutterVersionName == null) {
    flutterVersionName = '1.0.0'
}

android {
    namespace = "com.siro.siro_driver"
    compileSdk = 36
    ndkVersion "29.0.14033849"

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
        coreLibraryDesugaringEnabled true
    }

    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_17
    }

    externalNativeBuild {
        cmake {
            path "src/main/cpp/CMakeLists.txt"
            version "3.22.1"
        }
    }

    // تمت الإضافة: توجيه مسار المكتبات الأصلية لمطابقة تطبيق الراكب
    sourceSets {
        main {
            jniLibs.srcDirs = ['src/main/jniLibs']
        }
    }

    defaultConfig {
        applicationId = "com.siro.siro_driver"
        minSdkVersion = 30
        targetSdk = 36
        versionCode = flutterVersionCode.toInteger()
        versionName = flutterVersionName
        multiDexEnabled = true

        ndk {
            abiFilters "armeabi-v7a", "arm64-v8a"
        }
        
        manifestPlaceholders += [mapsApiKey: keystoreProperties['mapsApiKey'] ?: ""]

        // تمت الإضافة: تمرير تعليمات 16 KB لمترجم C++
        externalNativeBuild {
            cmake {
                arguments "-DANDROID_SUPPORT_FLEXIBLE_PAGE_SIZES=ON"
            }
        }
    }

    // تمت الإضافة: منع ضغط المكتبات لتتوافق مع متطلبات نظام التشغيل
    packaging {
        jniLibs {
            useLegacyPackaging = false
        }
    }

    signingConfigs {
       release {
           keyAlias keystoreProperties['keyAlias']
           keyPassword keystoreProperties['keyPassword']
           storeFile keystoreProperties['storeFile'] ? file(keystoreProperties['storeFile']) : null
           storePassword keystoreProperties['storePassword']
       }
   }

   buildTypes {
       release {
           signingConfig signingConfigs.release
           minifyEnabled true
           shrinkResources true
           proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
       }
   }
}

flutter {
    source = "../.."
}

dependencies {
    implementation "androidx.car.app:app:1.4.0"
    implementation "org.maplibre.gl:android-sdk:11.0.0"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    // تمت الترقية لتطابق تطبيق الراكب
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:2.1.5'
    

    implementation 'com.scottyab:rootbeer-lib:0.1.2'
    
    // تمت الترقية لتطابق تطبيق الراكب
    implementation 'com.google.android.gms:play-services-safetynet:18.1.0'
    
    implementation "androidx.concurrent:concurrent-futures:1.2.0" 
}